blogOSX

Un AppleScript (droplet) écrit, après avoir été fortement inspiré par la lecture de Stacks Overlays, dans le but de simplifier la mise en place d'overlays, leur personnalisation^[1] et de les rendre un peu plus fonctionnels. L'utilisation de script au format progiciel (.app) n'aura, évidemment, d'intérêt que dans le cadre d'une utilisation avec des stacks classés par date de modification.

AppleScript

property type_list : {"icns"}
 
on run
	set {path2me, text item delimiters} to {path to me as string, ":"}
	set {path2me, o_path2me} to {text items of path2me, path2me}
	
	set {i, path2dir, r} to {1, "", ((count of text items of path2me) - 1)}
	repeat r times
		set {path2dir, i} to {(path2dir & text item i of path2me & ":") as string, i + 1}
		if i = r then exit repeat
	end repeat
	
	tell application "Finder"
		activate
		make new Finder window to path2dir
	end tell
	
	future(o_path2me)
end run
 
on open thefiles
	repeat with i in thefiles
		set icns to item 1 of thefiles
		set icns to POSIX path of icns
		set item_info to info for POSIX file icns
	end repeat
	
	if (name extension of item_info) is in the type_list then
		do shell script "cp -f -R " & quoted form of icns & space & (quoted form of ((POSIX path of (path to me)) & "Contents/Resources/droplet.icns") as Unicode text)
	end if
	
	future(path to me)
end open
 
on future(p)
	if p does not contain "Script Editor.app" then
		set {f_year, c_date, text item delimiters} to ¬
			{(((do shell script "date '+%Y'") as integer) + 10), (do shell script "date '+%m%d%H%M.%S'"), ""}
		
		do shell script "touch -mt " & ((f_year & c_date & space) as string) & quoted form of ((POSIX path of (path to me)) as Unicode text)
	end if
end future

Comme on peut le constater, il s'agit d'un droplet, qui changera d'icône par simple glisser-déposer ; pour des raisons évidentes de droits il ne sera fourni qu'avec l'icône d'origine, libre à vous d'utiliser les Stack icons de Susumu, par exemple.

Capture d'écran

Télécharger "Stack Overlay.app"

Stack Overlay.app (image disque Mac OS X, ±48 Ko).

Pour changer l'icône de l'application, un simple glisser déposer suffit ! Dupliquez et placez "Stack Overlay.app" dans chaque dossier de stack trié par date de modification… le tout, de façon assez similaire à cet article : Stacks Overlays.

Évidemment, si vous utilisez cette petite application, toute remarque ou suggestion est la bienvenue^[2]…